The Code Therapy

Raijin Realm

An audio-reactive piece made to obtain horizontal lightning bolts through some simple vertical offset iterations disturbed by noise, with simplex-noise clouds as background and some light shafts (God rays) post-processing effects.

Created by marcogomez on Wed, 10 Nov 2021 11:37:52 GMT.

Author Twitter Profile: TheCodeTherapy
Author Website: https://mgz.me

lightning, bolt, electricity, fog, clouds, fbm, God rays


#version 300 es
// ╔═════════════╦════════════════╗
// ║ Marco Gomez ║ https://mgz.me ║
// ╚═════════════╩════════════════╝
precision highp float;

#define audioreactive

uniform sampler2D prgm4Texture;
uniform sampler2D prgm3Texture;
uniform vec2 resolution;

out vec4 fragColor;

void main(void) {
  vec2 uv = gl_FragCoord.xy / resolution.xy;
  vec4 tex = texture(prgm4Texture, uv);
  fragColor = tex;
}


#version 300 es
// ╔═════════════╦════════════════╗
// ║ Marco Gomez ║ https://mgz.me ║
// ╚═════════════╩════════════════╝
precision highp float;

uniform vec2 resolution;
uniform float time;
uniform float audiotime;
uniform float fft;
uniform float fftLow;
uniform float fftHigh;
uniform float fftLowNormalized;
uniform float fftMidNormalized;
uniform float fftHighNormalized;

out vec4 fragColor;

const float BPM = 120.0;

const float PI = acos(-1.0);
const float TAU = PI * 2.0;
const float bgWaveSpeed = 2.0;
const float xDistMag = 0.05;
const float yDistMag = 0.05;
const float xSineCycles = TAU;
const float ySineCycles = TAU;
const float ttp = 1.0 / 3.0;
const float ssp = 1.0 / 6.0;
const float seventh = 1.0 / 7.0;

const float cloudDensity = 1.2;
const float noisiness = 0.7;
const float speed = 0.1;
const float cloudHeight = 1.5;

float osc(float s, float e, float t, float ts) {
  return (e - s) * 0.5 + s + sin(t * ts) * (e - s) * 0.5;
}

float hashA(float x) {
  vec2 n = vec2(x * 0.99, x * 1.01);
  return fract(52.982919 * fract(dot(vec2(0.06711, 0.00584), n)));
}

float hashB(float x) {
  vec2 n = vec2(x * 1.01, x * 0.99);
  n = fract(n * vec2(5.3987, 5.4421));
  n += dot(n.yx, n.xy + vec2(21.5351, 14.3137));
  float xy = n.x * n.y;
  return fract(xy * 95.4307) + fract(xy * 75.04961) - 1.0;
}

float gaussian(float z, float u, float o) {
  return (
    (1.0 / (o * sqrt(TAU))) *
    (exp(-(((z - u) * (z - u)) / (2.0 * (o * o)))))
  );
}

vec3 hue(vec3 col, float a) {
  const vec3 k = vec3(0.57735, 0.57735, 0.57735);
  float c = cos(a);
  return col * c + cross(k, col) * sin(a) + k * dot(k, col) * (1.0 - c);
}

vec3 gaussgrain(float t) {
  vec2 ps = vec2(1.0) / resolution.xy;
  vec2 uv = gl_FragCoord.xy * ps;
  float seed = dot(uv, vec2(12.9898, 78.233));
  float noise = fract(sin(seed) * 43758.5453123 + t);
  noise = gaussian(noise, 0.0, 0.5);
  return vec3(noise);
}

float noise(float x) {
  float f = fract(x);
  float hashCA = hashA(floor(x)); float hashCB = hashA(floor(x) + 1.0);
  float noiseC = mix(hashCA, hashCB, f);
  float hashFA = hashB(floor(x)); float hashFB= hashB(floor(x) + 1.0);
  float noiseF = mix(hashFA, hashFB, f);
  float n = mix(noiseC, noiseF, 0.5);
  return n;
}

vec3 mod289(vec3 x) { return x - floor(x * (1.0 / 289.0)) * 289.0; }

vec4 mod289(vec4 x) { return x - floor(x * (1.0 / 289.0)) * 289.0; }

vec4 permute(vec4 x) { return mod289(((x * 34.0) + 1.0) * x); }

vec4 taylorInvSqrt(vec4 r) { return 1.79284291400159 - 0.85373472095314 * r; }

float snoise(vec3 v) {
  const vec2 C = vec2(ssp, ttp);
  const vec4 D = vec4(0.0, 0.5, 1.0, 2.0);
  vec3 i = floor(v + dot(v, C.yyy));
  vec3 x0 = v - i + dot(i, C.xxx);
  vec3 g = step(x0.yzx, x0.xyz);
  vec3 l = 1.0 - g;
  vec3 i1 = min(g.xyz, l.zxy);
  vec3 i2 = max(g.xyz, l.zxy);
  vec3 x1 = x0 - i1 + C.xxx;
  vec3 x2 = x0 - i2 + C.yyy;
  vec3 x3 = x0 - D.yyy;
  i = mod289(i);
  vec4 p = permute(
    permute(
      permute(
        i.z + vec4(0.0, i1.z, i2.z, 1.0)
      ) + i.y + vec4(0.0, i1.y, i2.y, 1.0)
    ) + i.x + vec4(0.0, i1.x, i2.x, 1.0)
  );
  float n_ = seventh;
  vec3 ns = n_ * D.wyz - D.xzx;
  vec4 j = p - 49.0 * floor(p * ns.z * ns.z);
  vec4 x_ = floor(j * ns.z);
  vec4 y_ = floor(j - 7.0 * x_);
  vec4 x = x_ *ns.x + ns.yyyy;
  vec4 y = y_ *ns.x + ns.yyyy;
  vec4 h = 1.0 - abs(x) - abs(y);
  vec4 b0 = vec4(x.xy, y.xy);
  vec4 b1 = vec4(x.zw, y.zw);
  vec4 s0 = floor(b0) * 2.0 + 1.0;
  vec4 s1 = floor(b1) * 2.0 + 1.0;
  vec4 sh = -step(h, vec4(0.0));
  vec4 a0 = b0.xzyw + s0.xzyw * sh.xxyy;
  vec4 a1 = b1.xzyw + s1.xzyw * sh.zzww;
  vec3 p0 = vec3(a0.xy, h.x);
  vec3 p1 = vec3(a0.zw, h.y);
  vec3 p2 = vec3(a1.xy, h.z);
  vec3 p3 = vec3(a1.zw, h.w);
  vec4 norm = taylorInvSqrt(
    vec4(dot(p0, p0), dot(p1, p1), dot(p2, p2), dot(p3, p3))
  );
  p0 *= norm.x; p1 *= norm.y; p2 *= norm.z; p3 *= norm.w;
  vec4 m = max(
    0.6 - vec4(dot(x0, x0), dot(x1, x1), dot(x2, x2), dot(x3, x3)),
    0.0
  );
  m = m * m;
  return (42.0 * dot(m * m, vec4(dot(p0, x0), dot(p1, x1), dot(p2, x2), dot(p3, x3))));
}

const float maximum = (
  1.0 / 1.0 + 1.0 / 2.0 + 1.0 / 3.0 + 1.0 / 4.0 +
  1.0 / 5.0 + 1.0 / 6.0 + 1.0 / 7.0 + 1.0 / 8.0
);

float fbm(vec3 uv) {
  float sum = 0.0;
  for (int i = 0; i < 8; ++i) {
    float f = float(i + 1);
    sum += snoise(uv * f + fftLow * 0.1) / f;
  }
  return sum / maximum;
}

float gradient(vec2 uv) {
  return (1.0 - uv.y * uv.y * cloudHeight);
}

void main(void) {
  float t = time * 0.5 + 5.0;
  float minRes = min (resolution.x, resolution.y);
  vec2 fc = gl_FragCoord.xy / minRes;
  float wt = time * bgWaveSpeed;
  float xAngle = wt + fc.y * ySineCycles;
  float yAngle = wt + fc.x * xSineCycles;
  bool bxHalf, byHalf;
  vec2 distortOffset = vec2(sin(xAngle), sin(yAngle)) * vec2(xDistMag, yDistMag);
  float frameScale = 29.97;
  float frameTime = floor(time * frameScale) / frameScale;
  vec2 uv = (2.0 * gl_FragCoord.xy - resolution.xy) / resolution.y;
  float fn = fftHighNormalized * 1.5;
  float boltsAmount = round(9.0 + fn);
  float threshold = (sqrt(fn * fn * fn) * 1.5) * fftMidNormalized + fft;
  uv *= 1.0 + smoothstep(0.0, fftLowNormalized * 0.35, threshold);
  uv *= (0.95 + fft * 0.3 - fftLow * fftLow * 0.1);
  vec3 col = mix(
    vec3(0.00, 0.05, 0.10),
    vec3(0.01, 0.02, 0.07),
    1.0 - length(uv * 0.25)
  ) + gaussgrain(frameTime) * 0.1;
  float t1 = 21.0;
  float t2 = 42.6;
  float t3 = 64.0;
  float t4 = 85.6;
  float t5 = 132.0;
  float t6 = 176.0;
  if (audiotime >= t1 && audiotime <= t2) {
    col = hue(col, 3.0) * 1.2;
  } else if (audiotime > t2 && audiotime <= t3) {
    uv *= 1.0 - fftHigh * 0.7;
  } else if (audiotime > t3 && audiotime <= t4) {
    uv *= 1.0 - fftHigh * 0.2;
    col = hue(col, audiotime + fftHigh * 4.0);
  } else if (audiotime > t4 && audiotime <= t5) {
    distortOffset *= 1.5 * (1.0 + fftHigh * 1.5);
    col *= 0.0;
  } else if (audiotime > t5 && audiotime < t6) {
    uv *= 1.0 - fftHigh * 0.42;
    col = hue(col, audiotime + fftHigh * 8.0) * 0.5;
  }
  col += vec3(2.0 - length(uv) - 0.5) / 5.0;
  col *= 0.5;
  vec3 p = vec3(vec2(uv.x, uv.y - t * 0.3), time * speed);
  vec3 offset = vec3(0.1, 0.3, 0.2);
  vec2 duv = vec2(fbm(p), fbm(p + offset)) * noisiness;
  duv += distortOffset * (0.5 + fftLow * fftLow * 8.0);
  float q = gradient(uv + duv) * cloudDensity;
  col *= vec3(q) * (1.1 + fftLowNormalized * 0.4);
  float off, y, f;
  for (float i = 0.0; i < boltsAmount; i++) {
    off = (fract(t * (1.0 + (boltsAmount - i) / boltsAmount * 0.5) + i / 7.0 + i / 8.0) * 0.13 - 0.13 / 2.0);
    off *= 1.25;
    y = off * 2.0 + (1.0 - uv.x * uv.x) * off;
    float rnd = hashB(floor(t * 3.0 + i));
    y += sin(uv.x * 1.6 + (t) * (3.0) + rnd * 3.5 + i * 80.0) / 3.0;
    rnd = hashB(floor(t * 2.0));
    y += (noise(uv.x * 6.0 + t * 1.0 + rnd * (10.5 + i * 8.0)) / 5.0);
    y = mix(y, 0.0, abs(uv.x / 2.0) / 1.2);
    y *= 1.0 + fftLowNormalized * fftLowNormalized;
    float exponent = 16.0 + (fftHighNormalized * 2.0);
    float f = pow(abs(0.91 - smoothstep(0.02, 0.75, pow(abs(y - uv.y), 0.5))), exponent);
    vec3 c = mix(vec3(1.0), vec3(1.3, 1.9, 4.0), 0.01 + fftHighNormalized * 5.0);
    col = clamp(mix(col, c, clamp(f, 0.0, 1.0)), 0.0, 1.0);
  }
  float highThreshold = smoothstep(0.0, 0.5, fftHigh);
  if (
    audiotime > t5 && audiotime <= t5 + 0.5 ||
    audiotime > t4 - 0.6 && audiotime < t4 + 0.4
  ) { col *= fftHigh; }
  fragColor = vec4(clamp(mix(col, col * col, 0.5 - clamp(highThreshold, 0.0, 0.5)), 0.0, 1.0), 1.0);
}


#version 300 es
// ╔═════════════╦════════════════╗
// ║ Marco Gomez ║ https://mgz.me ║
// ╚═════════════╩════════════════╝
precision highp float;

uniform sampler2D prgm1Texture;
uniform vec2 resolution;
uniform float time;
uniform float fft;

out vec4 fragColor;

#define inputTexture prgm1Texture

const float PI = acos(-1.0);
const float TAU = PI * 2.0;
const float h = 0.003;
const float v = 0.005;
const float g = 0.05;

float stepm(float a, float b, float c) {
  return step(c, sin(time + a * cos(time * b)));
}

vec3 badVHS(vec2 uv, sampler2D tex) {
  float tmod = mod(time * 0.25, 3.0);
  float lookyMod = uv.y - tmod;
  float window = 1.0 / (1.0 + 20.0 * lookyMod * lookyMod);
  float lookyStep = stepm(4.0, 4.0, 0.3) * 0.5;
  uv.x = uv.x + sin(uv.y * 10.0 + time) / 100.0 * lookyStep * (1.0 + cos(time * 80.0)) * window * 0.25;
  float vShift = v * stepm(2.0, 3.0, 0.9) * (sin(time) * sin(time * 20.0) + (0.5 + 0.1 * sin(time * 200.0) * cos(time)));
  uv.y = mod(uv.y + vShift, 5.0);
  vec3 desatColor;
  float _r, _g, _b;
  float x = sin(0.3 * time + uv.y * 21.0) * sin(0.7 * time + uv.y * 29.0) * sin(0.3 + 0.33 * time + uv.y * 31.0) * h;
  _r = texture(tex, vec2(x + uv.x + 0.001, uv.y + 0.001)).x + 0.007;
  _g = texture(tex, vec2(x + uv.x + 0.000, uv.y - 0.002)).y + 0.007;
  _b = texture(tex, vec2(x + uv.x - 0.002, uv.y + 0.000)).z + 0.007;
  _r += 0.08 * texture(tex, 0.75 * vec2(x +  0.012, -0.013) + vec2(uv.x + 0.001, uv.y + 0.001)).x;
  _g += 0.05 * texture(tex, 0.75 * vec2(x + -0.011, -0.010) + vec2(uv.x + 0.000, uv.y - 0.002)).y;
  _b += 0.08 * texture(tex, 0.75 * vec2(x + -0.010, -0.009) + vec2(uv.x - 0.002, uv.y + 0.000)).z;
  float _luma = 0.3 * _r + 0.6 * _g + 0.1 * _b;
  float _desat = 0.3;
  desatColor = vec3(
    _r + _desat * (_luma - _r),
    _g + _desat * (_luma - _g),
    _b + _desat * (_luma - _b)
  );
  desatColor = clamp(desatColor, 0.0, 1.0);
  return desatColor;
}

float oscillate(float s, float e, float t) {
  return (e - s) * 0.5 + s + sin(t) * (e - s) * 0.5;
}

float gaussian(float z, float u, float o) {
  return (
    (1.0 / (o * sqrt(TAU))) *
    (exp(-(((z - u) * (z - u)) / (2.0 * (o * o)))))
  );
}

vec3 gaussgrain(float t) {
  vec2 ps = vec2(1.0) / resolution.xy;
  vec2 uv = gl_FragCoord.xy * ps;
  float seed = dot(uv, vec2(12.9898, 78.233));
  float noise = fract(sin(seed) * 43758.5453123 + t);
  noise = gaussian(noise, 0.0, 0.5);
  return vec3(noise);
}

void main(void) {
  vec2 uv = gl_FragCoord.xy / resolution.xy;
  float frameScale = 29.97;
  float frameTime = floor(time * frameScale) / frameScale;
  vec3 grain = gaussgrain(frameTime);
  vec3 vhsCol = badVHS(uv, inputTexture) + (grain * grain) * g;
  float vig = (0.0 + 1.0 * 21.0 * uv.x * uv.y * (1.0 - uv.x) * (1.0 - uv.y));
  vhsCol *= vec3(pow(abs(vig), 0.5));
  float scans = clamp(0.35 + 0.35 * sin(3.5 * time + uv.y * resolution.y * 1.5), 0.0, 1.0);
  float s = pow(scans, 1.33);
  vhsCol = vhsCol * vec3(1.4 + 1.7 * s);
  if (uv.x < 0.0 || uv.x > 1.0 || uv.y < 0.0 || uv.y > 1.0) { vhsCol *= 0.0; }
  vhsCol *= 1.0 - 0.37 * vec3(clamp((mod(gl_FragCoord.x, 2.0) - 1.0) * 2.0, 0.0, 1.0));
  fragColor = vec4(vhsCol, 1.0);
}


#version 300 es
// ╔═════════════╦════════════════╗
// ║ Marco Gomez ║ https://mgz.me ║
// ╚═════════════╩════════════════╝
precision highp float;

uniform sampler2D prgm1Texture;
uniform vec2 resolution;
uniform float time;
uniform int frame;
uniform float fftHighNormalized;

out vec4 fragColor;

#define inputTexture prgm1Texture

vec3 hash33(vec3 p3) {
  p3 = fract(p3 * vec3(0.1031, 0.1030, 0.0973));
  p3 += dot(p3, p3.yxz + 19.19);
  return fract((p3.xxy + p3.yxx) * p3.zyx);
}

void main(void) {
  vec2 uv = gl_FragCoord.xy / resolution.xy;
  vec4 tex = texture(inputTexture, uv);
  vec4 col = tex;
  float w = 0.1;
  vec2 a = vec2(uv.x - 0.5, uv.y - 0.66);
  vec2 b = a * 0.15 / float(10.0);
  vec3 h = hash33(vec3(gl_FragCoord.xy, frame));
  uv += b * h.x;
  for (float i = 1.0; i > 0.9; i-= 0.000625) {
    uv -= 0.5;
    uv *= i;
    uv += 0.5;
    col += texture(inputTexture, uv) * w * (1.25 + fftHighNormalized * 0.85);
    w *= 0.98;
  }
  col *= 0.9;
  fragColor = mix(tex, col, 0.5);
}


#version 300 es
// ╔═════════════╦════════════════╗
// ║ Marco Gomez ║ https://mgz.me ║
// ╚═════════════╩════════════════╝
precision highp float;

uniform sampler2D noiseTexture;
uniform sampler2D prgm2Texture;
uniform sampler2D prgm3Texture;
uniform vec2 resolution;
uniform float time;
uniform float fft;

out vec4 fragColor;

const float amount = 1.0;
const float saturation = 0.8;
const vec2 vignetteSize = vec2(0.25, 0.25);
const float vignetteRoundness = 0.12;
const float vignetteMix = 1.0;
const float vignetteSmoothness = 0.42;
const float W = 1.2;
const float T = 7.5;

vec4 rgbShift(vec2 p , vec4 shift) {
  shift *= 2.0 * shift.w - 1.0;
  vec2 rs = vec2(shift.x, -shift.y);
  vec2 gs = vec2(shift.y, -shift.z);
  vec2 bs = vec2(shift.z, -shift.x);
  float r = texture(prgm2Texture, p + rs, 0.0).x;
  float g = texture(prgm2Texture, p + gs, 0.0).y;
  float b = texture(prgm2Texture, p + bs, 0.0).z;
  return vec4(r,g,b,1.0);
}

vec4 noise(vec2 uv) {
  return texture(noiseTexture, uv, 0.0);
}

vec4 vec4pow(vec4 v, float p) {
  return vec4(
    pow(v.x, p),
    pow(v.y, p),
    pow(v.z, p),
    v.w
  );
}

float filmicReinhardCurve(float x) {
  float q = (T * T + 1.0) * x * x;
  return q / (q + x + T * T);
}

vec3 filmicReinhard(vec3 c) {
  float w = filmicReinhardCurve(W);
  return vec3(
    filmicReinhardCurve(c.r),
    filmicReinhardCurve(c.g),
    filmicReinhardCurve(c.b)
  ) / w;
}

vec3 contrastSaturationBrightness(vec3 color, float brt, float sat, float con) {
  const float AvgLumR = 0.5;
  const float AvgLumG = 0.5;
  const float AvgLumB = 0.5;
  const vec3 LumCoeff = vec3(0.2125, 0.7154, 0.0721);
  vec3 AvgLumin = vec3(AvgLumR, AvgLumG, AvgLumB);
  vec3 brtColor = color * brt;
  vec3 intensity = vec3(dot(brtColor, LumCoeff));
  vec3 satColor = mix(intensity, brtColor, sat);
  vec3 conColor = mix(AvgLumin, satColor, con);
  return conColor;
}

float sdSquare(vec2 point, float width) {
  vec2 d = abs(point) - width;
  return min(max(d.x, d.y), 0.0) + length(max(d, 0.0));
}

float vignette(vec2 uv, vec2 size, float roundness, float smoothness) {
  uv -= 0.5;
  float minWidth = min(size.x, size.y);
  uv.x = sign(uv.x) * clamp(abs(uv.x) - abs(minWidth - size.x), 0.0, 1.0);
  uv.y = sign(uv.y) * clamp(abs(uv.y) - abs(minWidth - size.y), 0.0, 1.0);
  float boxSize = minWidth * (1.0 - roundness);
  float dist = sdSquare(uv, boxSize) - (minWidth * roundness);
  return 1.0 - smoothstep(0.0, smoothness, dist);
}

void main(void) {
  vec2 uv = gl_FragCoord.xy / resolution.xy;
  vec2 mo = uv * 2.0 - 1.0;
  mo *= 0.1;
  float reinhardAmount = 0.4 + fft * 0.6;
  float contrast = 1.0 + fft * 0.25;
  float brightness = 1.0 + fft;
  vec3 chromaticAberration;
  chromaticAberration.r = texture(prgm2Texture, uv - mo * 0.05, 0.0).r;
  chromaticAberration.g = texture(prgm2Texture, uv - mo * 0.15, 0.0).g;
  chromaticAberration.b = texture(prgm2Texture, uv - mo * 0.25, 0.0).b;
  vec4 texA = vec4(vec3(0.0), 1.0);
  texA.xyz = mix(texA.xyz, chromaticAberration, 0.3);
  const float speed = 0.005;
  const float amplitude = 0.025;
  vec4 shift = vec4pow(
    noise(
      vec2(speed * time, speed * time / 25.0 )
    ), 8.0
  ) * vec4(vec3(amplitude), 1.0);
  vec4 shiftB = vec4pow(
    noise(
      vec2(speed * time * 1.5, speed * time * 1.5 / 25.0 )
    ), 8.0
  ) * vec4(vec3(amplitude), 1.0);
  texA += rgbShift(uv, shift);
  texA += rgbShift(uv, shiftB);
  vec4 texB = texture(prgm3Texture, uv);
  vec4 tex = mix(texA, texB, 0.25);
  tex = mix(tex, tex * tex, 0.5);
  vec3 reinhard = filmicReinhard(tex.rgb);
  vec3 color = tex.rgb;
  color = mix(color, reinhard, reinhardAmount);
  color = contrastSaturationBrightness(color, brightness, saturation, contrast);
  float v = vignette(uv, vignetteSize, vignetteRoundness, vignetteSmoothness);
  vec3 vig = color * v;
  color = mix(color, vig, vignetteMix);
  color = mix(tex.xyz, color, amount);
  color = clamp(color, 0.0, 1.0);
  fragColor = vec4(color, 1.0);
}